Hopefully "ScriptingTipsAndTricks" helps you with your batch file or vbscript scripting :-)\Windows CommandsCALL internal subroutine or external batch (.cmd)

---

CALL internal subroutine or external batch (.cmd)

In the following we will call the internal subroutine ":FIND_EXE".

@echo off
setlocal
set BatchFileDir=%~dp0
cls

CALL :FIND_EXE "Exiv2Exe" "exiv2.exe"
   if     "%Exiv2Exe%" == "" echo "exiv2.exe" not found
   if not "%Exiv2Exe%" == "" echo "exiv2.exe" found full name: "%Exiv2Exe%"
goto :EOF

@rem ++++++++++++++++++++++++++ v11.366
:FIND_EXE
@rem ++++++++++++++++++++++++++
   set Look4Exe=%~2
   set   FndExe=
   if exist "%BatchFileDir%%Look4Exe%"                                    set FndExe=%BatchFileDir%%Look4Exe%
   if "%FndExe%" == "" if exist "%Look4Exe%" for %%f in ("%Look4Exe%") do set FndExe=%%~ff
   if "%FndExe%" == ""   for %%f in ("%Look4Exe%") do                     set FndExe=%%~$PATH:f
   set %~1=%FndExe%
   goto :EOF

SYNTAX: CALL /?

Calls one batch program from another.

CALL [drive:][path]filename [batch-parameters]

  batch-parameters   Specifies any command-line information required by the
                     batch program.

If Command Extensions are enabled CALL changes as follows:

CALL command now accepts labels as the target of the CALL.  The syntax
is:

    CALL :label arguments

A new batch file context is created with the specified arguments and
control is passed to the statement after the label specified.  You must
"exit" twice by reaching the end of the batch script file twice.  The
first time you read the end, control will return to just after the CALL
statement.  The second time will exit the batch script.  Type GOTO /?
for a description of the GOTO :EOF extension that will allow you to
"return" from a batch script.

In addition, expansion of batch script argument references (%0, %1,
etc.) have been changed as follows:


    %* in a batch script refers to all the arguments (e.g. %1 %2 %3
        %4 %5 ...)

    Substitution of batch parameters (%n) has been enhanced.  You can
    now use the following optional syntax:

        %~1         - expands %1 removing any surrounding quotes (")
        %~f1        - expands %1 to a fully qualified path name
        %~d1        - expands %1 to a drive letter only
        %~p1        - expands %1 to a path only
        %~n1        - expands %1 to a file name only
        %~x1        - expands %1 to a file extension only
        %~s1        - expanded path contains short names only
        %~a1        - expands %1 to file attributes
        %~t1        - expands %1 to date/time of file
        %~z1        - expands %1 to size of file
        %~$PATH:1   - searches the directories listed in the PATH
                       environment variable and expands %1 to the fully
                       qualified name of the first one found.  If the
                       environment variable name is not defined or the
                       file is not found by the search, then this
                       modifier expands to the empty string

    The modifiers can be combined to get compound results:

        %~dp1       - expands %1 to a drive letter and path only
        %~nx1       - expands %1 to a file name and extension only
        %~dp$PATH:1 - searches the directories listed in the PATH
                       environment variable for %1 and expands to the
                       drive letter and path of the first one found.
        %~ftza1     - expands %1 to a DIR like output line

    In the above examples %1 and PATH can be replaced by other
    valid values.  The %~ syntax is terminated by a valid argument
    number.  The %~ modifiers may not be used with %*

Please email me any feedback, additional information or corrections. See this page online (look for updates) ScriptingTipsAndTricks© is (C)opyright Dennis Bareis 2003-2008 (All rights reserved). Sunday September 07 2014 at 12:50pm Visit ScriptingTipsAndTricks's Home Page