Hopefully "ScriptingTipsAndTricks" helps you with your batch file or vbscript scripting :-)
[Bottom][Contents][Prev]: Dot Net Versions - uses ASoft .NET Version Detector tool to get list[Next]: Environment Variable Indirection - one variable contains full or partial name of another
\->Batch Files->Drag and Drop From Explorer - need to be careful about double quotes

[anchor]

The Code for: "Drag and Drop From Explorer [need to be careful about double quotes].cmd"

This is the example, a shortcut was installed to this code :

@echo off
::@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
:: $Header:   C:/DBAREIS/Projects.PVCS/Win32/ScriptingTipsAndTricks/EXAMPLE[cmd].Drag and Drop From Explorer [need to be careful about double quotes].cmd.pvcs   1.0   11 Jul 2014 19:31:00   USER "Dennis"  $
::@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
setlocal

:KEEP_ASKING
    ::--- Ask for File/folder and wait for response ------------------
    set DroppedFileOrDir=
    echo Drop Folder or FILE from explorer (ENTER to Quit)
    set /P DroppedFileOrDir=--^> &rem

    ::--- Items Dropped from Explorer probably quoted (remove them) ---
    set DroppedFileOrDir=#%DroppedFileOrDir%
    set  DroppedFileOrDir=%DroppedFileOrDir:"=%
    set  DroppedFileOrDir=%DroppedFileOrDir:~1%

    ::--- Now its safe to see if empty (and exit) --------------------
    echo.
    if "%DroppedFileOrDir%" == "" echo Aborting as requested...&echo.& goto :EOF

    ::--- Display the shortname --------------------------------------
    set TYPE=FILE
    if     exist "%DroppedFileOrDir%\." set TYPE=DIRECTORY
    if not exist "%DroppedFileOrDir%"   set TYPE=MISSING, TYPED IN BY USED?
    echo [%TYPE%] "%DroppedFileOrDir%"
    echo.
    echo +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    echo.
goto KEEP_ASKING

Please note that that I am not trying to show how great I am by producing batch files 9,000 characters long on one line that no one will understand or be able to debug when they go wrong. I am going out of my way to comment the code and make it verbose so beginners and advanced users will both benefit. I don't claim to be an expert that knows everything, if I'm wrong or make a mistake then please contact me and let me know :-)


Microsoft awarded me an MVP (Most Valuable Professional award) in 2004, 2005, 2006, 2007, 2008 & 2009 for the Windows SDK (Windows Installer) area.Please email me any feedback, additional information or corrections.
See this page online (look for updates)

[Top][Contents][Prev]: Dot Net Versions - uses ASoft .NET Version Detector tool to get list[Next]: Environment Variable Indirection - one variable contains full or partial name of another


ScriptingTipsAndTricks© is (C)opyright Dennis Bareis 2003-2008 (All rights reserved).
Sunday September 07 2014 at 12:50pm
Visit ScriptingTipsAndTricks's Home Page
Microsoft awarded me an MVP (Most Valuable Professional award) in 2004, 2005, 2006, 2007, 2008 & 2009 for the Windows SDK (Windows Installer) area.